' Gambas module file

' Description:

' Pachube.module

' Support for Pachube (pronounce: patch-bay) sensors network.

' Development Status:

' Just build, so possible bugs around.

' Links:

' http://www.pachube.com

' DomotiGa - an open source home automation program.

' Copyright(C) 2009 Ron Klinkien

' Read file called COPYING for license details.

PUBLIC hPost AS NEW HttpClient AS "hPost"

PUBLIC tPachube AS Timer

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' start timer

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB Run()

  ' start poll timer for Pachube

  tPachube = NEW Timer AS "tPachube"

  tPachube.Delay = Main.iPachubePushTime * 1000 * 60 ' multiply for minutes

  tPachube.Start

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' gets called at each timer event

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB tPachube_Timer()

  UploadPachubeData()

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' create xml data and upload it to the service

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB UploadPachubeData()

  DIM sContent AS String

  ' if we are already uploading return

  IF hPost.Status > 0 THEN

    Main.WriteLog(("I'm already uploading EEML data to Pachube, skipping."))

    RETURN

  END IF

  ' create xml string

  sContent = CreatePachubeData()

  ' use httpclient to post xml to service

  hPost.URL = "https://www.pachube.com/api/feeds/" & Main.iPachubeFeed & ".xml?_method=put&key=" & Main.sPachubeAPIKey

  hPost.TimeOut = 10

  hPost.Async = TRUE

  hPost.Post("text/xml", sContent)

  IF Main.bPachubeDebug THEN Main.WriteDebugLog("[Pachube] " & sContent)

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' scan pachube devices table and create xml document

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PRIVATE FUNCTION CreatePachubeData() AS String

  DIM sXml, sValue, sTag AS String

  DIM rResult AS Result

  DIM aTags AS String[]

  ' scan device table

  rResult = Main.hDB.Exec("SELECT * FROM devices_pachube")

  IF NOT rResult THEN

    Main.WriteLog(("Error: table 'devices_pachube' not found!"))

    RETURN

  END IF

  ' build header

  sXml = "<?xml version='1.0' encoding='UTF-8'?>\n"

  sXml &= "<eeml xmlns='http://www.eeml.org/xsd/005' xmlns:xsi='http://www.w3.org/2001/XMLSchema-instance' xsi:schemaLocation='http://www.eeml.org/xsd/005 http://www.eeml.org/xsd/005/005.xsd'>\n"

  sXml &= "<environment>\n"

  ' create device entries

  IF rResult.Count THEN

    FOR EACH rResult

      sXml &= "<data id='" & rResult!datastreamid & "'>\n"

      aTags = Split(rResult!tags, ",")

      IF aTags.Count > 0 THEN

        FOR EACH sTag IN aTags

          sXml &= "<tag>" & LTrim(sTag) & "</tag>\n"

        NEXT

      ELSE

        sXml &= "<tag>" & rResult!tags & "</tag>\n"

      END IF

      SELECT rResult!value

        CASE "Value"

          sValue = Devices.GetCurrentValueForDevice(rResult!deviceid)

        CASE "Value2"

          sValue = Devices.GetCurrentValue2ForDevice(rResult!deviceid)

        CASE "Value3"

          sValue = Devices.GetCurrentValue3ForDevice(rResult!deviceid)

        CASE "Value4"

          sValue = Devices.GetCurrentValue3ForDevice(rResult!deviceid)

      END SELECT

      sXml &= "<value>" & sValue & "</value>\n"

      sXml &= "<unit symbol='" & rResult!devicelabel & "' type='" & rResult!unittype & "'>" & rResult!units & "</unit>\n"

      sXml &= "</data>\n"

    NEXT

  END IF

  ' close document

  sXml &= "</environment>\n"

  sXml &= "</eeml>\n"

  RETURN sXml

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' catch error

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB hPost_Error()

  Main.WriteDebugLog(("[Pachube] EEML data post error."))

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' check http return code

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB hPost_Finished()

  DIM iCount AS Integer

  ' select on http result code and display message

  SELECT hPost.Code

    CASE 200

      Main.WriteLog(("Uploaded EEML data to Pachube."))

    CASE 401

      Main.WriteLog(("Error authenticating while uploading EEML data to Pachube!"))

    CASE 403

      Main.WriteLog(("Error forbidden to upload EEML data to Pachube!"))

    CASE 404

      Main.WriteLog(("Error page not found while uploading EEML data to Pachube!"))

    CASE 422

      Main.WriteLog(("Error EEML data is not valid after uploading to Pachube!"))

    CASE 503

      Main.WriteLog(("Error rate limit exceeded while uploading EEML data to Pachube!"))

    CASE ELSE

      Main.WriteLog(("Unknown error occured while uploading EEML data to Pachube!"))

  END SELECT

  ' if debug is on print all http headers

  IF NOT Main.bPachubeDebug THEN RETURN

  FOR iCount = 0 TO hPost.Headers.Count - 1

    Main.WriteDebugLog("[Pachube] " & Left(hPost.Headers[iCount], Len(hPost.Headers[iCount]) - 1))

  NEXT

END