' Gambas class file

' Description:

' FTVGuide.class

' Form for showing TV guide.

' Development Status:

' Imported from Kris's own project, needs testing.

' DomotiGa - an open source home automation program.

' Copyright(C) 2008-2010 Ron Klinkien

' This module is written by and Copyright(C) 2009 Kris Wauters on February, 14th - 2010

' For more info or help, mailto: kris@digitalplayground.be

' Read file called COPYING for license details.

PUBLIC SUB Form_Open()

  IF Main.bTVGuideEnabled THEN

    TxtDate.text = Format(Now, "dd/mm/yyyy")

    'LoadPreview(Main.DateFromAppToSQL(TxtDate.text))

    ChkProgramName.Value = TRUE

  ELSE

    TxtDate.Enabled = FALSE

    BtnSearch.Enabled = FALSE

    BtnPreview.Enabled = FALSE

    ChkProgramDescription.Enabled = FALSE

    ChkProgramName.Enabled = FALSE

    TxtSearch.Enabled = FALSE

  END IF

END

PUBLIC SUB Form_Resize()

  frmPreview.Move(4, 30, ME.ClientWidth - 8, ME.ClientHeight - 30)

  ScrollPrograms.Move(127, 40, ME.ClientWidth - 142, ME.ClientHeight - 94)

  ScrollScale.Move(127, 2, ME.ClientWidth - 140, 35)

  ScrollChannels.Move(7, 40, 119, ME.ClientHeight - 110)

  LblInfo.Move(7, ME.ClientHeight - 50, ME.ClientWidth - 25, 15)

END

' this is where all the *magic* happens, make a preview of the TVguide-data that sits in the database

PRIVATE SUB LoadPreview(StrDate AS String)

  '--- declare variables ---

  DIM rResChannel, rResProgram AS Result

  DIM TmpBtnChannel, TmpBtnProgram AS Button

  DIM TmpLbl AS Label

  DIM SepLine AS Separator

  DIM IntChannelCount, IntWidth, IntLeft, IntI, IntStartHour, IntStartMinute, IntStopHour, IntStopMinute AS Integer

  DIM BoolOK AS Boolean

  DIM StrFileLogo AS String

  '--- first remove previous childs ---

  FOR IntI = ScrollChannels.Children.Count - 1 TO 0 STEP -1

    ScrollChannels.Children[IntI].Delete

  NEXT

  FOR IntI = ScrollPrograms.Children.Count - 1 TO 0 STEP -1

    ScrollPrograms.Children[IntI].Delete

  NEXT

  '--- set datelabel ---

  LblDate.text = Format(Date(CInt(Left(StrDate, 4)), CInt(Mid(StrDate, 5, 2)), CInt(Mid(StrDate, 7, 2))), "dddd") & gb.newline & Format(Date(CInt(Left(StrDate, 4)), CInt(Mid(StrDate, 5, 2)), CInt(Mid(StrDate, 7, 2))), "dd mmmm yyyy")

  'FrmPreview.Enabled = FALSE

  Application.Busy = TRUE

  '--- setup 2 dummy labels to "fullfill" the correct width ---

  TmpLbl = NEW Label(ScrollPrograms)

  TmpLbl.X = 0

  TmpLbl.Width = 24 * 480

  TmpLbl.text = ""

  TmpLbl.Transparent = TRUE

  TmpLbl = NEW Label(ScrollScale)

  TmpLbl.X = 0

  TmpLbl.Width = 24 * 480

  TmpLbl.text = ""

  TmpLbl.Transparent = TRUE

  '--- put Hour-scale on top of scrollbox ---

  FOR IntI = 0 TO 24

    '--- Hours ---

    IF IntI > 0 THEN

      TmpLbl = NEW Label(ScrollScale)

      TmpLbl.Width = 50

      TmpLbl.ForeColor = Color.DarkRed

      TmpLbl.Alignment = Align.Center

      IF IntI = 24 THEN

        TmpLbl.Text = "[" & Format(IntI, "00") & ":00]"

      ELSE

        TmpLbl.Text = "[" & Format(IntI, "00") & ":00]"

      END IF

      TmpLbl.Y = 1

      TmpLbl.X = (IntI * 480) - (TmpLbl.Width / 2)

      SepLine = NEW Separator(ScrollScale)

      SepLine.Y = 25

      SepLine.Height = 15

      SepLine.BackColor = Color.DarkRed

      SepLine.Width = 2

      SepLine.X = (IntI * 480)

      ScrollPrograms.ScrollX = SepLine.X - (ScrollScale.Width / 2)

    END IF

    '--- Half Hours ---

    IF IntI < 24 THEN

      TmpLbl = NEW Label(ScrollScale)

      TmpLbl.Width = 50

      TmpLbl.ForeColor = Color.DarkRed

      TmpLbl.Alignment = Align.Center

      TmpLbl.Text = "[" & Format(IntI, "00") & ":30]"

      TmpLbl.Y = 1

      TmpLbl.X = (IntI * 480) - (TmpLbl.Width / 2) + 240

      SepLine = NEW Separator(ScrollScale)

      SepLine.Y = 25

      SepLine.Height = 15

      SepLine.BackColor = Color.DarkRed

      SepLine.Width = 2

      SepLine.X = (IntI * 480) + 240

      ScrollPrograms.ScrollX = SepLine.X - (ScrollScale.Width / 2)

    END IF

  NEXT

  '--- next, loop trough all marked channels, and display the programinfo ---

  rResChannel = Main.hDB.Exec("SELECT * FROM tv_channels WHERE isUsed = 1 ORDER BY ChannelOrder")

  'rResChannel = Main.hDB.Exec("SELECT * FROM tv_channels ORDER BY ChannelOrder")

  IntChannelCount = 0

  IF rResChannel THEN

    IF rResChannel.Count > 0 THEN

      FOR EACH rResChannel

        IF IntChannelCount / 5 = Int(IntChannelCount / 5) THEN

          LblInfo.text = "Rendering channel " & CStr(IntChannelCount) & " from " & CStr(rResChannel.Count)

          LblInfo.Refresh

          WAIT

        ENDIF

        IntChannelCount = IntChannelCount + 1

        TmpBtnChannel = NEW Button(ScrollChannels)

        TmpBtnChannel.BackColor = Color.White

        TmpBtnChannel.Border = Border.None

        TmpBtnChannel.Mouse = Mouse.Pointing

        TmpBtnChannel.X = 0

        TmpBtnChannel.Y = (IntChannelCount - 1) * 42

        TmpBtnChannel.Width = 119

        TmpBtnChannel.Height = 43

        TmpBtnChannel.Action = "Channel|" & rResChannel!ChannelID

        IF Len(rResChannel!BLOBlogo.data) > 10 THEN

          StrFileLogo = Main.BlobFromDB("SELECT * FROM tv_channels WHERE RecID=" & rResChannel!RecID, "BLOBlogo", "EXTlogo")

          TmpBtnChannel.Picture = Picture.Load(StrFileLogo)

        ELSE

          TmpBtnChannel.Text = rResChannel!ChannelName

        ENDIF

        '--- next, read program info for the current channel ---

        BoolOK = FALSE

        rResProgram = Main.hDB.Exec("SELECT tv_programs.*,tv_categories.BackColor,tv_categories.ForeColor FROM tv_programs,tv_categories WHERE tv_programs.CategoryName = tv_categories.CategoryName AND (left(EndPoint,8) = '" & Left(StrDate, 8) & "' OR left(StartPoint,8) = '" & Left(StrDate, 8) & "') AND ChannelID = '" & rResChannel!ChannelID & "' ORDER BY StartPoint")

        IF rResProgram THEN

          IF rResProgram.Count > 0 THEN 

            BoolOK = TRUE

            FOR EACH rResProgram

              TmpBtnProgram = NEW Button(ScrollPrograms)

              IF Len(Trim(rResProgram!BackColor)) = 0 THEN

                TmpBtnProgram.BackColor = Color.White

              ELSE

                TmpBtnProgram.BackColor = Val(rResProgram!BackColor)

              END IF

              IF Len(Trim(rResProgram!ForeColor)) = 0 THEN

                TmpBtnProgram.ForeColor = Color.Black

              ELSE

                TmpBtnProgram.ForeColor = Val(rResProgram!ForeColor)

              END IF

              TmpBtnProgram.Border = Border.None

              TmpBtnProgram.Mouse = Mouse.Pointing

              TmpBtnProgram.Action = "Program|" & rResChannel!ChannelID & "|" & rResProgram!StartPoint

              TmpBtnProgram.Text = rResProgram!ProgramName & gb.newline & Mid(rResProgram!StartPoint, 9, 2) & ":" & Mid(rResProgram!StartPoint, 11, 2) & " - " & Mid(rResProgram!EndPoint, 9, 2) & ":" & Mid(rResProgram!EndPoint, 11, 2)

              TmpBtnProgram.ToolTip = TmpBtnProgram.Text

              TmpBtnProgram.Y = TmpBtnChannel.Y

              TmpBtnProgram.Height = TmpBtnChannel.Height

              IF Left(rResProgram!StartPoint, 8) <> StrDate THEN

                IntStartHour = 0

                IntStartMinute = 0

              ELSE

                IntStartHour = CInt(Mid(rResProgram!StartPoint, 9, 2))

                IntStartMinute = CInt(Mid(rResProgram!StartPoint, 11, 2))

              END IF

              IF Left(rResProgram!EndPoint, 8) <> StrDate THEN

                IntStopHour = 24

                IntStopMinute = 00

              ELSE

                IntStopHour = CInt(Mid(rResProgram!EndPoint, 9, 2))

                IntStopMinute = CInt(Mid(rResProgram!EndPoint, 11, 2))

              END IF

              IntLeft = (IntStartHour * 480) + (IntStartMinute * 8)

              IntWidth = ((IntStopHour * 480) + (IntStopMinute * 8)) - ((IntStartHour * 480) + (IntStartMinute * 8))

              TmpBtnProgram.X = IntLeft

              TmpBtnProgram.Width = IntWidth

            NEXT

          END IF

        END IF

        IF BoolOK = FALSE THEN

          '--- add dummy label, to get the exact same height in both scrollviews

          TmpLbl = NEW Label(ScrollPrograms)

          TmpLbl.Y = TmpBtnChannel.Y

          TmpLbl.X = 0

          TmpLbl.Width = 24 * 480

          TmpLbl.Height = TmpBtnChannel.Height

          TmpLbl.Text = ""

          TmpLbl.Transparent = TRUE

        END IF

      NEXT

    END IF

  END IF

  '--- re-enable frame, because otherwise positioning of scrollview is not possible ---

  Application.Busy = FALSE

  'FrmPreview.Enabled = TRUE

  '--- draw the "current time line" (do this only if the current date is today) ---

  IF Format(Now, "yyyymmdd") = StrDate THEN

    SepLine = NEW Separator(ScrollPrograms)

    SepLine.Y = 1

    SepLine.Height = ScrollPrograms.ScrollHeight - 2

    SepLine.BackColor = Color.Red

    SepLine.Width = 2

    SepLine.X = ((CInt(Format(Now, "hh")) * 480) + (CInt(Format(Now, "nn")) * 8))

    ScrollPrograms.ScrollX = SepLine.X - (ScrollPrograms.Width / 2)

    'LblInfo.text = ("Guide contains ") & CStr(rResChannel.Count) & (" channels.")

    LblInfo.Text = ""

  END IF

END

PUBLIC SUB BtnPreview_Click()

  LoadPreview(Main.DateFromAppToSQL(TxtDate.text))

END

PUBLIC SUB ScrollPrograms_Scroll()

  ScrollChannels.ScrollY = ScrollPrograms.ScrollY

  ScrollScale.ScrollX = ScrollPrograms.ScrollX

END

'--- handles the clicking action of the dynamically generated channel- & program-labels ---

PUBLIC SUB Action_Activate(key AS String) AS Boolean

  '--- declare variables ---

  DIM rRes AS Result

  DIM FrmTmpProgram AS NEW FTVGuideProgramDetail

  DIM FrmTmpChannel AS NEW FTVGuideChannelDetail

  DIM StrFile, StrTmpDate AS String

  SELECT CASE UCase(Main.ParseTag(key, 1, "|"))

    CASE "CHANNEL"

      FrmTmpChannel.tag = Main.ParseTag(Key, 2, "|") & "|" & Main.DateFromAppToSQL(TxtDate.Text)

      FrmTmpChannel.ShowDialog

    CASE "PROGRAM"

      rRes = Main.hDB.Exec("SELECT tv_programs.*,tv_channels.ChannelName,tv_channels.RecID as TVChannelRecID,tv_channels.BLOBlogo FROM tv_programs,tv_channels WHERE tv_programs.ChannelID = tv_channels.ChannelID AND tv_programs.ChannelID = '" & Main.ParseTag(key, 2, "|") & "' AND tv_programs.StartPoint = '" & Main.ParseTag(key, 3, "|") & "'")

      IF rRes THEN

        IF rRes.count > 0 THEN

          rRes.MoveFirst

          FrmTmpProgram.LblChannel.text = rRes!ChannelName

          FrmTmpProgram.LblDate.text = Main.DateFromSQLToApp(Left(rRes!StartPoint, 8))

          FrmTmpProgram.LblTime.Text = "[" & Main.TimeFromSQLToApp(Right(rRes!StartPoint, 4)) & " - " & Main.TimeFromSQLToApp(Right(rRes!EndPoint, 4)) & "]" 

          FrmTmpProgram.LblCategory.text = rRes!CategoryName

          FrmTmpProgram.LblSubCategory.text = rRes!SubCategoryName

          FrmTmpProgram.LblProgramName.text = rRes!ProgramName

          FrmTmpProgram.TxtProgramDescription.text = rRes!ProgramDescription

          StrTmpDate = Left(rRes!StartPoint, 8)

          FrmTmpProgram.LblDateDay.text = Format(Date(CInt(Left(StrTmpDate, 4)), CInt(Mid(StrTmpDate, 5, 2)), CInt(Mid(StrTmpDate, 7, 2))), "dddd")

          IF Len(rRes!BLOBlogo.data) > 10 THEN

            StrFile = Main.BlobFromDB("SELECT * FROM tv_channels WHERE RecID=" & rRes!TVChannelRecID, "BLOBlogo", "EXTlogo")

            FrmTmpProgram.PicLogo.Picture = Picture.Load(StrFile)

          END IF

          FrmTmpProgram.ShowDialog

        END IF

      END IF

      rRes = NULL

  END SELECT

END

PUBLIC SUB DtChooser_Change()

  '--- declare variables ---

  DIM rRes AS Result

  DIM StrDate AS String

  '--- take care that the selected date is within the min/max-range of the items in the tv_programs table ---

  StrDate = Format(DtChooser.Year, "0000") & Format(DtChooser.Month, "00") & Format(DtChooser.Day, "00")

  rRes = Main.hDB.Exec("SELECT MIN(StartPoint) AS MinDate, MAX(EndPoint) AS MaxDate FROM tv_programs")

  IF rRes THEN

    IF rRes.count > 0 THEN

      rRes.MoveFirst

      IF StrDate < Left(rRes!MinDate, 8) THEN

        DtChooser.value = Date(CInt(Left(rRes!MinDate, 4)), CInt(Mid(rRes!MinDate, 5, 2)), CInt(Mid(rRes!MinDate, 7, 2)))

      END IF

      IF StrDate > Left(rRes!MaxDate, 8) THEN

        DtChooser.value = Date(CInt(Left(rRes!MaxDate, 4)), CInt(Mid(rRes!MaxDate, 5, 2)), CInt(Mid(rRes!MaxDate, 7, 2)))

      END IF

    END IF

  END IF

  rRes = NULL

  TxtDate.text = Format(DtChooser.Day, "00") & "/" & Format(DtChooser.Month, "00") & "/" & Format(DtChooser.Year, "0000")

END

PUBLIC SUB DtChooser_Leave()

  DtChooser.Visible = FALSE

END

PUBLIC SUB TxtDate_Enter()

  IF Main.bTVGuideEnabled THEN

    IF TxtDate.Text = "00/00/0000" THEN

      DtChooser.Value = Now

    ELSE

      DtChooser.Value = Date(CInt(Mid(TxtDate.Text, 7, 4)), CInt(Mid(TxtDate.text, 4, 2)), CInt(Left(TxtDate.text, 2)))

    END IF

    DtChooser.Visible = TRUE

  END IF

END

PUBLIC SUB BtnSearch_Click()

  '--- declare variables ---

  DIM StrQuery AS String

  DIM FrmTmp AS NEW FTVGuideSearchDetail

  '--- at least one checkbox needs to be marked ! ---

  IF ChkProgramDescription.value = FALSE AND ChkProgramName.value = FALSE THEN

    Message.Info(("At least one checkbox need to be marked for a search !"))

    RETURN

  END IF

  '--- also, search with empty search-string is not allowed ---

  IF Len(Trim(TxtSearch.text)) < 1 THEN

    Message.Info(("No search-criteria found !"))

    RETURN

  ENDIF

  '--- if we are here, we can perform a search, so build a query ---

  StrQuery = "SELECT tv_channels.RecID,tv_channels.ChannelOrder, tv_channels.ChannelName,tv_channels.ChannelID,tv_channels.BLOBlogo,tv_channels.EXTlogo,tv_programs.* FROM tv_channels,tv_programs where tv_channels.ChannelID = tv_programs.ChannelID AND tv_channels.IsUsed=1"

  IF ChkProgramName.value = TRUE AND ChkProgramDescription.value = FALSE THEN

    StrQuery = StrQuery & " AND tv_programs.ProgramName like '%" & TxtSearch.Text & "%'"

  END IF

  IF ChkProgramName.value = FALSE AND ChkProgramDescription.value = TRUE THEN

    StrQuery = StrQuery & " AND tv_programs.ProgramDescription like '%" & TxtSearch.Text & "%'"

  END IF

  IF ChkProgramName.value = TRUE AND ChkProgramDescription.value = TRUE THEN

    StrQuery = StrQuery & " AND (tv_programs.ProgramName like '%" & TxtSearch.Text & "%' OR tv_programs.ProgramDescription like '%" & TxtSearch.text & "%')"

  END IF

  StrQuery = StrQuery & " AND left(StartPoint,8) >= '" & Format(Now, "yyyymmdd") & "' ORDER BY StartPoint,tv_channels.ChannelOrder"

  FrmTmp.Tag = StrQuery & "|" & Format(Now, "yyyymmdd") & "|" & TxtSearch.Text

  IF ChkProgramName.value = TRUE THEN

    FrmTmp.Tag = FrmTmp.tag & "|1"

  ELSE

    FrmTmp.Tag = FrmTmp.tag & "|0"

  END IF

  IF ChkProgramDescription.value = TRUE THEN

    FrmTmp.Tag = FrmTmp.tag & "|1"

  ELSE

    FrmTmp.Tag = FrmTmp.tag & "|0"

  END IF

  FrmTmp.ShowDialog

END