' Gambas class file

' Description:

' CLEDMatrix.class

' Display messages on a LED Matrix.

' Development Status:

' Just started. Tested with Conrad McCrypt AM03127 display.

' Links:

' http://www.conrad.nl/goto.php?artikel=590996

' DomotiGa - an open source home automation program.

' Copyright(C) 2008-2010 Ron Klinkien

' Read file called COPYING for license details.

PROPERTY Port AS String

PROPERTY LEDMatrixDebug AS Boolean

PROPERTY DisplayID AS String

PROPERTY DisplayColor AS Integer

PROPERTY DisplaySpeed AS Integer

PRIVATE sPort AS String

PRIVATE bLEDMatrixDebug AS Boolean

PRIVATE sDisplayID AS String

PRIVATE iDisplayColor AS Integer

PRIVATE iDisplaySpeed AS Integer

PUBLIC hLEDMatrix AS NEW SerialPort

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' open serial port

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC FUNCTION Connect() AS Boolean

  ' try to close the port

  TRY hLEDMatrix.Close

  ' get a new one

  hLEDMatrix = NEW Serialport AS "LEDMatrix"

  WITH hLEDMatrix

    .PortName = sPort

    .Speed = 9600

    .Parity = 0

    .DataBits = 8

    .StopBits = 1

    .FlowControl = 0

    .Open()

  END WITH

  ' all ok

  RETURN TRUE

CATCH ' some errors

  Main.WriteLog(("LED Matrix Error: ") & ERROR.Text)

  RETURN FALSE

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' display startup text

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC FUNCTION Run() AS Boolean

  ' DisplayMessage(sDisplayID, Application.Name & " Rocks!!")

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' display message

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB DisplayMessage(sDisplayID AS String, sMessage AS String, OPTIONAL iColor AS Integer, OPTIONAL iSpeed AS Integer)

  DIM sColor AS String[] = ["A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "P", "Q", "R", "S"]

  DIM sSpeed AS String[] = ["q", "a", "Q", "A"]

  IF NOT iColor THEN iColor = iDisplayColor

  IF NOT iSpeed THEN iSpeed = iDisplaySpeed

  SendCommand(sDisplayID, "<L1><PA><FE><M" & sSpeed[iSpeed] & "><WC><FE><C" & sColor[iColor] & ">" & sMessage)

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' set real time clock

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB SetClock(sDisplayID AS String)

  DIM sWeek AS String

  SELECT CASE LCase(Format(Now, "ddd"))

    CASE "mon"

      sWeek = "01"

    CASE "tue"

      sWeek = "02"

    CASE "wed"

      sWeek = "03"

    CASE "thu"

      sWeek = "04"

    CASE "fri"

      sWeek = "05"

    CASE "sat"

      sWeek = "06"

    CASE "sun"

      sWeek = "07"

  END SELECT

  ' YYWWMMDDHHmmSS

  SendCommand(sDisplayID, "<SC>" & Format(Now, "yy") & sWeek & Format(Now, "mmddhhnnss"))

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' calculate checksum

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PRIVATE SUB CalcChecksum(sData AS String) AS String

  DIM iChecksum AS Byte = Asc(Left(sData, 1))

  DIM iCnt AS Integer

  FOR iCnt = 2 TO Len(sData)

    iChecksum = iChecksum XOR Asc(Mid(sData, iCnt, 1))

  NEXT

  RETURN Hex(iChecksum, 2)

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' send command string to display

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PRIVATE SUB SendCommand(sDisplayID AS String, sCmd AS String)

  DIM sStr AS String

  DIM iCnt AS Integer

  sStr = "<ID0" & sDisplayID & ">" & sCmd & CalcChecksum(sCmd) & "<E>"

  IF Main.bLEDMatrixDebug THEN Main.WriteDebugLog(("[LEDMatrix] Sending string: ") & sStr)

  PRINT #hLEDMatrix, sStr

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' read display response

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC SUB LEDMatrix_Read()

  DIM sData AS Byte

  READ #hLEDMatrix, sData

  IF Main.bLEDMatrixDebug THEN Main.WriteDebugLog(("[LEDMatrix] Received string: ") & sData)

END

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

' close port

'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

PUBLIC FUNCTION Disconnect() AS Boolean

  ' try to close the connection

  TRY hLEDMatrix.Close

  Main.WriteLog(("LED Matrix serial port close."))

  ' all ok

  RETURN TRUE

CATCH ' some errors

  Main.WriteLog(("LED Matrix Error: ") & ERROR.Text)

  RETURN FALSE

END

' implement properties

FUNCTION Port_Read() AS String

  RETURN sPort

END

SUB Port_Write(Value AS String)

  sPort = Value

END

PRIVATE FUNCTION LEDMatrixDebug_Read() AS Boolean

  RETURN bLEDMatrixDebug

END

PRIVATE SUB LEDMatrixDebug_Write(Value AS Boolean)

  bLEDMatrixDebug = Value

END

PRIVATE FUNCTION DisplayID_Read() AS String

  RETURN sDisplayID

END

PRIVATE SUB DisplayID_Write(Value AS String)

  sDisplayID = Value

END

PRIVATE FUNCTION DisplayColor_Read() AS Integer

  RETURN iDisplayColor

END

PRIVATE SUB DisplayColor_Write(Value AS Integer)

  iDisplayColor = Value

END

PRIVATE FUNCTION DisplaySpeed_Read() AS Integer

  RETURN iDisplaySpeed

END

PRIVATE SUB DisplaySpeed_Write(Value AS Integer)

  iDisplaySpeed = Value

END