DomotiGa - /trunk/DomotiGaServer/Thermostat.module - DomotiGa

The files contained in this repository can be downloaded to your computer using a svn client.
On Linux you simply type the command displayed below.

Subversion

This URL has Read-Only access.

Statistics

root / trunk / DomotiGaServer / Thermostat.module @ 769

History | View | Annotate | Download (10.3 kB)

 ' Gambas module file
 ' Description:
 ' Thermostat.module
 ' Support for thermostat functionality.
 ' Development Status:
 ' Started.
 ' DomotiGa - an open source home automation program.
 ' Copyright(C) 2008-2011 Ron Klinkien
 ' Read file called COPYING for license details.
 PUBLIC tThermostat AS Timer
 PUBLIC NO_TEMP AS Integer = 1000
 PRIVATE aDerogatedHeating AS NEW Collection
 PRIVATE aPreviousRequestedTemperature AS NEW Collection
 PUBLIC SUB Run()
   ' start poll timer for digitemp
   tThermostat = NEW Timer AS "tThermostat"
   tThermostat.Delay = Main.iThermostatPollTime * 1000
   tThermostat.Start
 END
 '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 ' gets called at each timer event
 '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 PUBLIC SUB tThermostat_Timer()
   ' do the job
   DoTheJob()
 END
 PUBLIC SUB DoTheJob()
   DIM dtCurrent AS Date
   DIM iScen, iHeat AS Integer
   DIM rSched, rHeat AS Result
   DIM fRequestedTemp, fMeasuredTemp AS Float
   DIM sStatusDev, sStatusReg, sDeviceName, sRegulatorName AS String
   DIM sOnDev AS String = "On"
   DIM sOffDev AS String = "Off"
   DIM sOnReg AS String = "On"
   DIM sOffReg AS String = "Off"
   DIM bOutOfDeviceOffset AS Boolean
   ' get current date/time
   dtCurrent = Now()
   ' get active scenario
   iScen = GetActiveScenario()
   ' get scenario's schedules
   rSched = Main.hDB.Exec("SELECT * FROM thermostat_schedule WHERE scenario=&1", iScen)
   IF rSched THEN
     IF rSched.Count THEN
     ' for each schedule
       FOR EACH rSched
         ' get schedule's heating
         iHeat = rSched!heating
         rHeat = Main.hDB.Exec("SELECT * FROM thermostat_heating WHERE id=&1", iHeat)
         IF rHeat THEN
           IF rHeat.Count THEN
             IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Working on heating : " & rHeat!name)
             ' check for constant change
             fRequestedTemp = GetRequestedTempForHeating(iScen, iHeat)
             IF aPreviousRequestedTemperature.Exist(iHeat) THEN
               IF aPreviousRequestedTemperature[iHeat] <> fRequestedTemp THEN
                 DeleteDerogateHeating(iHeat)
                 IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Ending derogation for : " & rHeat!name)
               ENDIF
               aPreviousRequestedTemperature[iHeat] = fRequestedTemp
             ELSE
               aPreviousRequestedTemperature.Add(fRequestedTemp, iHeat)
             ENDIF
             ' get requested temp
             fRequestedTemp = GetDerogateHeating(iHeat)
             IF fRequestedTemp = NO_TEMP THEN
               fRequestedTemp = GetRequestedTempForHeating(iScen, iHeat)
             ENDIF
             ' get real temp
             fMeasuredTemp = CFloat(Replace(Devices.GetCurrentValueForDevice(rHeat!sensor, 1), ",", ".", gb.String))
             IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Requested temp is : " & fRequestedTemp & "/Measured temp is : " & fMeasuredTemp)
             sDeviceName = Devices.FindNameForDevice(rHeat!device)
             sStatusDev = Devices.GetValueForDevice(sDeviceName)
             IF rHeat!regulator <> 0 THEN
               sRegulatorName = Devices.FindNameForDevice(rHeat!regulator)
               IF sRegulatorName THEN
                   sStatusReg = Devices.GetValueForDevice(sRegulatorName)
               END IF
             ELSE
               sRegulatorName = ""
             ENDIF
             IF rHeat!deviceInverted = TRUE THEN
               sOnDev = "Off"
               sOffDev = "On"
             ELSE
               sOnDev = "On"
               sOffDev = "Off"
             ENDIF
             IF rHeat!regulatorInverted = TRUE THEN
               sOnReg = "Off"
               sOffReg = "On"
             ELSE
               sOnReg = "On"
               sOffReg = "Off"
             ENDIF
             bOutOfDeviceOffset = FALSE
             IF NOT (isInsideLatency(rHeat!device, rHeat!deviceLatency)) THEN
               ' compare requested temp to sensor's one
               IF fMeasuredTemp + rHeat!deviceOffsetBottom <= fRequestedTemp THEN
               ' too cold
               bOutOfDeviceOffset = TRUE
                 IF String.Comp(sStatusDev, sOffDev, gb.text) = 0 THEN
                   IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Too cold here. Switching On device : " & sDeviceName)
                   Devices.SetDevice(sDeviceName, sOnDev)
                   sStatusDev = sOnReg
                 ENDIF
                 IF sRegulatorName THEN
                   IF String.Comp(sStatusReg, sOffReg, gb.text) = 0 THEN
                     IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Too cold here. Switching On regulator : " & sRegulatorName)
                     Devices.SetDevice(sRegulatorName, sOnReg)
                     sStatusReg = sOnReg
                   ENDIF
                 ENDIF
               ENDIF
               IF fMeasuredTemp - rHeat!deviceOffsetTop >= fRequestedTemp THEN
               ' too hot
                 bOutOfDeviceOffset = TRUE
                 IF String.Comp(sStatusDev, sOnDev, gb.text) = 0 THEN
                   IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Too hot here. Switching Off device : " & sDeviceName)
                   Devices.SetDevice(sDeviceName, sOffDev)
                   sStatusDev = sOffReg
                 ENDIF
                 IF sRegulatorName THEN
                   IF String.Comp(sStatusReg, sOnReg, gb.text) = 0 THEN
                     IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Too hot here. Switching Off regulator : " & sRegulatorName)
                     Devices.SetDevice(sRegulatorName, sOffReg)
                     sStatusReg = sOffReg
                   ENDIF
                 ENDIF
               ENDIF
               IF NOT (bOutOfDeviceOffset) AND (String.Comp(sStatusDev, sOnDev, gb.text) = 0) THEN
                 IF sRegulatorName THEN
                   sStatusReg = Devices.GetValueForDevice(sRegulatorName)
                   IF fMeasuredTemp + rHeat!regulatorOffsetBottom <= fRequestedTemp THEN
                   ' little cold
                     IF String.Comp(sStatusReg, sOffReg, gb.text) = 0 THEN
                       IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Little cold here. Switching On regulator : " & sRegulatorName)
                       Devices.SetDevice(sRegulatorName, sOnReg)
                       sStatusReg = sOnReg
                     ENDIF
                   ENDIF
                   IF fMeasuredTemp - rHeat!regulatorOffsetTop >= fRequestedTemp THEN
                   ' little hot
                     IF String.Comp(sStatusReg, sOnReg, gb.text) = 0 THEN
                       IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Little hot here. Switching Off regulator : " & sRegulatorName)
                       Devices.SetDevice(sRegulatorName, sOffReg)
                       sStatusReg = sOffReg
                     ENDIF
                   ENDIF
                 ENDIF
               ENDIF
             ENDIF
           ENDIF
         ENDIF
       NEXT
     ENDIF
   ENDIF
 END
 PRIVATE FUNCTION GetActiveScenario() AS Integer
   DIM rResultScen AS result
   rResultScen = Main.hDB.Exec("SELECT id, name FROM thermostat_scenarii WHERE name=&1", Main.GlobalVar["Thermostat_Mode"])
   IF rResultScen THEN
     IF rResultScen.Count >= 1 THEN
       IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Active scenario is : " & Main.GlobalVar["Thermostat_Mode"])
       RETURN rResultScen!id
     ENDIF
   ENDIF
   RETURN 0
 END
 PUBLIC FUNCTION GetRequestedTempForHeating(iScenario AS Integer, iHeating AS Integer) AS Float
   DIM sSql AS String
   DIM rTemp AS Result
   DIM fReturn AS Float
   sSql = "SELECT curtime() as curtime, dayofweek(curdate()) as curday, day, time,name, value FROM `thermostat_schedule_entry` se , `thermostat_constant` "
   sSql &= " c where c.id=se.constant AND dayofweek(curdate()) = Day AND se.scenario = &1 AND se.heating = &2 order by Day, Time "
   rTemp = Main.hDB.Exec(sSql, iScenario, iHeating)
   IF rTemp THEN
     IF rTemp.Count THEN
       FOR EACH rTemp
         IF rTemp!curtime >= rTemp!time AND rTemp!curday >= rTemp!day THEN
           fReturn = rTemp!value
         ELSE
           BREAK
         ENDIF
       NEXT
       RETURN fReturn
     ENDIF
   ENDIF
   RETURN NO_TEMP
 END
 PUBLIC FUNCTION GetNextRequestedTempForHeating(iScenario AS Integer, iHeating AS Integer) AS Float
   DIM sSql AS String
   DIM rTemp AS Result
   DIM fCurrentReq, fReturn AS Float
   sSql = "SELECT curtime() as curtime,  time,name, value FROM `thermostat_schedule_entry` se , `thermostat_constant` "
   sSql = sSql & " c where c.id=se.constant AND dayofweek(curdate()) = Day AND se.scenario = &1 AND se.heating = &2 order by Time "
   rTemp = Main.hDB.Exec(sSql, iScenario, iHeating)
   IF rTemp THEN
     IF rTemp.Count THEN
       FOR EACH rTemp
         IF rTemp!curtime >= rTemp!time THEN
           ' before now
           fCurrentReq = rTemp!value
         ELSE
           fReturn = rTemp!value
           IF fCurrentReq <> fReturn THEN RETURN fReturn
         ENDIF
       NEXT
     ENDIF
   ENDIF
   RETURN NO_TEMP
 END
 PRIVATE FUNCTION isInsideLatency(iDevice AS Integer, iLatency AS Integer) AS Boolean
   DIM rDev AS Result
   rDev = Main.hDB.Exec("select * from devices where id=&1", iDevice)
   IF rDev THEN
     IF rDev.Count >= 1 THEN
       IF rDev!lastchanged THEN
         IF DateDiff(rDev!lastchanged, Now(), gb.Minute) <= iLatency THEN
           IF Main.bThermostatDebug THEN Main.WriteDebugLog("[Thermostat] Inside latency, nothing to do here.")
           RETURN TRUE
         ENDIF
       ENDIF
     ENDIF
   ENDIF
   RETURN FALSE
 END
 PUBLIC SUB SetDerogateHeating(iScen AS Integer, iHeat AS Integer, fTemp AS Float)
   IF aDerogatedHeating.Exist(iHeat) THEN
     IF GetRequestedTempForHeating(iscen, iheat) = fTemp THEN
       aDerogatedHeating.Remove(iHeat)
     ELSE
       aDerogatedHeating[iHeat] = fTemp
     ENDIF
   ELSE
     ' not found
     aDerogatedHeating.Add(fTemp, iHeat)
   ENDIF
 END
 PUBLIC FUNCTION GetDerogateHeating(iHeat AS Integer) AS Float
   IF aDerogatedHeating.Exist(iHeat) THEN
     RETURN aDerogatedHeating[iHeat]
   ELSE
     RETURN NO_TEMP
   ENDIF
 END
 PUBLIC SUB DeleteAllDerogateHeating()
   IF aDerogatedHeating.Count THEN
     Main.WriteLog("[Thermostat] Ending all derogated temp.")
     aDerogatedHeating.Clear
   ENDIF
 END
 PUBLIC SUB DeleteDerogateHeating(iHeat AS Integer)
   IF aDerogatedHeating.Exist(iHeat) THEN aDerogatedHeating.Remove(iHeat)
 END